2010

Asymptoteの練習 No.0005 テオドロスの螺線

sukarabe 2010年3月10日 (水) コメントはまだありません

引き続き、繰り返し処理。テオドロスの螺線 (Spiral of Theodorus) を描いてみる。
三辺が$1$, $1$, $\sqrt2$の直角三角形から始めて、斜辺の上に高さ1の直角三角形を次から次へと作っていくことで、この図形は作られている。

伝説(？)によれば、テオドロスはルート2から始めて、自然数の平方根が整数になる場合を除いて無理数になることの証明をルート17まで行ったという。この螺線における直角三角形の斜辺がちょうど$\sqrt2$, $\sqrt3$, … , $\sqrt{17}$ となっていて、これ以上進めると三角形が重なってしまうので、ここで止めたのだろうという話を何処かで読んだ。

繰り返し以外のポイントとしては、線分$OP_{i}$を90度回転させて長さを1にしたものを線分$P_{i}P_{i+1}$とすることで、次の直角三角形を作るところ。AsymptoteはMetapostと同様に複素数としての演算が出来るが、それ以外にも、アフィン変換がサポートされている。今回は rotate という回転を行うオペレーターと、単位ベクトルを作る unit という関数を用いた。

/*
  Asymptoteの練習 No.0005
  繰り返し処理
  Spiral of Theodorus (テオドロスの螺線)
  t0005.asy
*/

size(6cm,0); // 出来上がりの図版のサイズを幅6センチに設定

int n=17;
pair pO=(0,0);
pair[] pA;

pA[1]=(1,0);

for (int i=1; i<=n-1; i+=1)
  {
    pA[i+1]=pA[i]+unit(rotate(90)*(pA[i]-pO));
  }

for (int i=2; i<=n; i+=1)
  {
    draw(pO--pA[i-1]--pA[i]--cycle);
    markrightangle(pO,pA[i-1],pA[i],1.5mm);
    dot(format("$\mathrm{P}_{%i}$",i), pA[i],dir(pO--pA[i]));
  }

dot("$\mathrm{P}_{1}$", pA[1], dir(pO--pA[1]));

Asymptoteの練習 No.0004 正17角形を描く

sukarabe 2010年3月9日 (火) コメントはまだありません

Asymptoteで繰り返し処理をしてみる。for 文の構文はC言語とほぼ同じ。繰り返しの変数は，その場で定義すればよい。ローカル変数ということなのだろう。簡単なところで正多角形を描いてみる。

/*
  Asymptoteの練習 No.0004
  繰り返し処理
  t0004.asy
*/

size(6cm,0); // 出来上がりの図版のサイズを幅6センチに設定

int N=17;
pair pO=(0,0);
pair[] pA;

for (int i=0; i<=N; i+=1)
  {
    pA[i]=(cos(2*i*pi/N),sin(2*i*pi/N));
  }

for (int i=0; i<=N-1; i+=1)
  {
    draw(pA[i]--pA[i+1]);
    draw(pO--pA[i]);
    dot(format("$\mathrm{P}_{%i}$",i), pA[i],dir(pO--pA[i]));
  }

以前 Metapost で同じようなことをしたことがあるが，頂点のラベル付けで添え字を自動で書き込むことが出来なかった。Asymptoteでは format 文が用意されているので，繰り返し処理の中で，変数 i を文字(数字)に書き下してからTeX側に送ることが簡単に出来るようだ。これは便利だ。