カテゴリー: Asymptote

twitterのTLで今年のセンター試験・数学IAが難しくなってる，傾向が今までと違う，等々あったので，検索して問題をDLしてみた。いままでのセンターの問題とかほとんど見たことないので，どこがどう違うのかは分からないものの，第3問の幾何がちょっと面白そうだったので，図を描いてみた。

図が描いてあれば易しい問題だと思う。文章をちゃんと読んで，正しい図を描くことが存外難しいということなのであろう。

$\angle PAO=\theta$ とおけば，$\tan\theta=\frac{1}{3}$であるから，$\tan 2\theta=\frac{3}{4}$ となる。よって，三角形ABCは3辺の長さの比が$3:4:5$の直角三角形である。$AB=6$であるから，$AC=\frac{24}{5}$ となる。

三角形ABCの内接円の半径$r$は，この場合は直角三角形であるから，次のように相似を利用して簡単に求められる。
\[ AN:NC=AN:NQ=AD:DP=3:1 \]
であるから，
\[ r=\frac{1}{4}AC=\frac{6}{5} \]
これから，三角形ADPと三角形ANQの相似比は$5:6$と分かるから，
\[ PQ=\frac{1}{5}AP=\frac{\sqrt{10}}{5} \]

なお，図版は asymptote で描いた。備忘録的にソースを書いておく。

import fontsize;

defaultpen(fontsize(11));
dotfactor=6;
//pen dashed=linetype("6 6");
// pen dashed=linetype("3 3");
pen dashed=linetype("4 4");
pen thick=linewidth(0.6bp); // 太線用のペンを定義する。
pen hairline=linewidth(0.3pt);

defaultpen(linewidth(0.4bp)); // 線の太さを0.4ポイントに設定

// usepackage("amsmath");
usepackage("MinionPro");

import geometry;

/* 2点A, Bを結ぶ弧 */
path ConnectTwo(pair A, pair B, real OffSet) {
  pair M=(A+B)/2+OffSet*unit(B-A)*I;
  return A..M..B;
}


size(8cm,0);

point pO=(0,0), pP=(0,1);
circle cO=circle(pO,3), cP=circle(pP,1);

line T1=tangent(cP,pO-pP);
point[] pAB=intersectionpoints(T1,cO);
point pA=pAB[0], pB=pAB[1];

line tgs[]=tangents(cP,pA);
line T2=tgs[1];
point pD=intersectionpoints(T2,cP)[0];
point pC=intersectionpoints(T2,cO)[1];

point pE=2*pO-pC;

circle icABC=incircle(pA,pB,pC);
circle icCEA=incircle(pC,pE,pA);
point pQ=icABC.C, pR=icCEA.C;

point pT1=intersectionpoints(icABC,pA--pC)[0];
point pT2=intersectionpoints(icABC,pB--pC)[0];

point pM=intersectionpoints(pA--pP,pO--pD)[0];


real dist=0.15;
draw(Label(scale(0.9)*"\kern -0.5em\raise 1ex\hbox{$\frac{24}{5}-r$}", align=Center,filltype=UnFill), ConnectTwo(pA,pT1,3.7dist), hairline+dashed);

draw(Label(scale(0.9)*"$3$", align=Center,filltype=UnFill), ConnectTwo(pA,pD,1.5dist), hairline+dashed);
draw(Label(scale(0.9)*"$3$", align=Center,filltype=UnFill), ConnectTwo(pA,pO,-1.2dist), hairline+dashed);
draw(Label(scale(0.9)*"$3$", align=Center,filltype=UnFill), ConnectTwo(pO,pB,-1.2dist), hairline+dashed);
draw(Label(scale(0.9)*"$1$", align=Center,filltype=UnFill), ConnectTwo(pD,pP,dist), hairline+dashed);
draw(Label(scale(0.9)*"$1$", align=Center,filltype=UnFill), ConnectTwo(pO,pP,-dist), hairline+dashed);
draw(Label(scale(0.9)*"$r$", align=Center,filltype=UnFill), ConnectTwo(pT1,pQ,dist), hairline+dashed);
draw(Label(scale(0.9)*"$r$", align=Center,filltype=UnFill), ConnectTwo(pT1,pC,dist), hairline+dashed);


draw(cO);
draw(cP);
dot("A",pA, dir(pO--pA));
dot("B",pB,dir(pO--pB));
dot("O",pO,dir(pD--pP));
dot("D",pD,0.7dir(pQ--pD));
dot("C",pC,dir(pO--pC));
dot("P",pP,dir(pO--pQ));
dot("E",pE,dir(pO--pE));
dot("Q",pQ,dir(pP--pO));
dot("R",pR,dir(pP--pO));
dot("N",pT1,dir(pQ--pT1));
dot(pT2);

draw(pP--pO);
draw(pP--pD);
draw(pA--pB);
draw(pA--pC--pB);
draw(pC--pE--pA);
draw(icABC);
draw(icCEA);
draw(pQ--pT1);
draw(pQ--pT2);

draw(pO--pD,dashed);
draw(pA--pQ,dashed);

dot("M",pM,N);

markrightangle(pP,pO,pA,1.5mm);
markrightangle(pA,pD,pP,1.5mm);
markrightangle(pA,pC,pB,1.5mm);
markrightangle(pE,pA,pC,1.5mm);
markrightangle(pA,pM,pO,1.5mm);
markrightangle(pA,pT1,pQ,1.5mm);
markrightangle(pC,pT2,pQ,1.5mm);

markangle(scale(0.9)*Label("$\theta$"),radius=8mm,n=2,space=0.6mm, pO,pA,pP);
markangle(scale(0.9)*Label("$\theta$"),radius=8mm,n=2,space=0.6mm, pP,pA,pC);

addMargins(2mm,2mm);

引き続き、繰り返し処理。テオドロスの螺線 (Spiral of Theodorus) を描いてみる。
三辺が$1$, $1$, $\sqrt2$の直角三角形から始めて、斜辺の上に高さ1の直角三角形を次から次へと作っていくことで、この図形は作られている。

伝説(？)によれば、テオドロスはルート2から始めて、自然数の平方根が整数になる場合を除いて無理数になることの証明をルート17まで行ったという。この螺線における直角三角形の斜辺がちょうど$\sqrt2$, $\sqrt3$, … , $\sqrt{17}$ となっていて、これ以上進めると三角形が重なってしまうので、ここで止めたのだろうという話を何処かで読んだ。

繰り返し以外のポイントとしては、線分$OP_{i}$を90度回転させて長さを1にしたものを線分$P_{i}P_{i+1}$とすることで、次の直角三角形を作るところ。AsymptoteはMetapostと同様に複素数としての演算が出来るが、それ以外にも、アフィン変換がサポートされている。今回は rotate という回転を行うオペレーターと、単位ベクトルを作る unit という関数を用いた。

/*
  Asymptoteの練習 No.0005
  繰り返し処理
  Spiral of Theodorus (テオドロスの螺線)
  t0005.asy
*/

size(6cm,0); // 出来上がりの図版のサイズを幅6センチに設定

int n=17;
pair pO=(0,0);
pair[] pA;

pA[1]=(1,0);

for (int i=1; i<=n-1; i+=1)
  {
    pA[i+1]=pA[i]+unit(rotate(90)*(pA[i]-pO));
  }

for (int i=2; i<=n; i+=1)
  {
    draw(pO--pA[i-1]--pA[i]--cycle);
    markrightangle(pO,pA[i-1],pA[i],1.5mm);
    dot(format("$\mathrm{P}_{%i}$",i), pA[i],dir(pO--pA[i]));
  }

dot("$\mathrm{P}_{1}$", pA[1], dir(pO--pA[1]));

Asymptoteで繰り返し処理をしてみる。for 文の構文はC言語とほぼ同じ。繰り返しの変数は，その場で定義すればよい。ローカル変数ということなのだろう。簡単なところで正多角形を描いてみる。

/*
  Asymptoteの練習 No.0004
  繰り返し処理
  t0004.asy
*/

size(6cm,0); // 出来上がりの図版のサイズを幅6センチに設定

int N=17;
pair pO=(0,0);
pair[] pA;

for (int i=0; i<=N; i+=1)
  {
    pA[i]=(cos(2*i*pi/N),sin(2*i*pi/N));
  }

for (int i=0; i<=N-1; i+=1)
  {
    draw(pA[i]--pA[i+1]);
    draw(pO--pA[i]);
    dot(format("$\mathrm{P}_{%i}$",i), pA[i],dir(pO--pA[i]));
  }

以前 Metapost で同じようなことをしたことがあるが，頂点のラベル付けで添え字を自動で書き込むことが出来なかった。Asymptoteでは format 文が用意されているので，繰り返し処理の中で，変数 i を文字(数字)に書き下してからTeX側に送ることが簡単に出来るようだ。これは便利だ。